c.t.n.dir: add scan-dirs/scan-files with platform

Stuart Sierra · Stuart Sierra · commit 504e796f6b0a · 2015-07-31T11:49:33.000-04:00
Deprecate 'scan' and 'scan-all', replace with 'scan-dirs' and
'scan-files' taking optional argument for clj/cljs platform.
diff --git a/src/main/clojure/clojure/tools/namespace/dir.clj b/src/main/clojure/clojure/tools/namespace/dir.clj
@@ -11,57 +11,104 @@
   file-modification timestamps"}
   clojure.tools.namespace.dir
   (:require [clojure.tools.namespace.file :as file]
+            [clojure.tools.namespace.find :as find]
             [clojure.tools.namespace.track :as track]
             [clojure.java.classpath :refer [classpath-directories]]
             [clojure.java.io :as io]
             [clojure.set :as set]
             [clojure.string :as string])
   (:import (java.io File) (java.util.regex Pattern)))
 
-(defn- find-files [dirs]
+(defn- find-files [dirs platform]
   (->> dirs
        (map io/file)
        (filter #(.exists ^File %))
-       (mapcat file-seq)
-       (filter file/clojure-file?)
-       (map #(.getCanonicalFile ^File %))))
+       (mapcat #(find/find-sources-in-dir % platform))))
 
 (defn- modified-files [tracker files]
   (filter #(< (::time tracker 0) (.lastModified ^File %)) files))
 
 (defn- deleted-files [tracker files]
   (set/difference (::files tracker #{}) (set files)))
 
-(defn- update-files [tracker deleted modified]
+(defn- update-files [tracker deleted modified {:keys [read-opts]}]
   (let [now (System/currentTimeMillis)]
     (-> tracker
         (update-in [::files] #(if % (apply disj % deleted) #{}))
         (file/remove-files deleted)
         (update-in [::files] into modified)
-        (file/add-files modified)
+        (file/add-files modified read-opts)
         (assoc ::time now))))
 
-(defn scan
-  "Scans directories for files which have changed since the last time
-  'scan' was run; update the dependency tracker with
+(defn scan-files
+  "Scans files to find those which have changed since the last time
+  'scan-files' was run; updates the dependency tracker with
   new/changed/deleted files.
 
+  files is the collection of files to scan.
+
+  Optional third argument is map of options:
+
+    :platform  Either clj (default) or cljs, both defined in
+               clojure.tools.namespace.find, controls reader options for 
+               parsing files.
+
+    :add-all?  If true, assumes all extant files are modified regardless
+               of filesystem timestamps."
+  {:added "0.3.0"}
+  ([tracker files] (scan-files tracker files nil))
+  ([tracker files {:keys [platform add-all?]}]
+   (let [deleted (seq (deleted-files tracker files))
+         modified (if add-all?
+                    files
+                    (seq (modified-files tracker files)))]
+     (if (or deleted modified)
+       (update-files tracker deleted modified platform)
+       tracker))))
+
+(defn scan-dirs
+  "Scans directories for files which have changed since the last time
+  'scan-dirs' or 'scan-files' was run; updates the dependency tracker
+  with new/changed/deleted files.
+
+  dirs is the collection of directories to scan, defaults to all
+  directories on Clojure's classpath.
+
+  Optional third argument is map of options:
+
+    :platform  Either clj (default) or cljs, both defined in 
+               clojure.tools.namespace.find, controls file extensions 
+               and reader options.
+
+    :add-all?  If true, assumes all extant files are modified regardless
+               of filesystem timestamps."
+  {:added "0.3.0"}
+  ([tracker] (scan-dirs tracker nil nil))
+  ([tracker dirs] (scan-dirs tracker dirs nil))
+  ([tracker dirs {:keys [platform add-all?] :as options}]
+   (let [ds (or (seq dirs) (classpath-directories))]
+     (scan-files tracker (find-files ds platform) options))))
+
+(defn scan
+  "DEPRECATED: replaced by scan-dirs.
+
+  Scans directories for Clojure (.clj, .cljc) source files which have
+  changed since the last time 'scan' was run; update the dependency
+  tracker with new/changed/deleted files.
+
   If no dirs given, defaults to all directories on the classpath."
+  {:added "0.2.0"
+   :deprecated "0.3.0"}
   [tracker & dirs]
-  (let [ds (or (seq dirs) (classpath-directories))
-        files (find-files ds)
-        deleted (seq (deleted-files tracker files))
-        modified (seq (modified-files tracker files))]
-    (if (or deleted modified)
-      (update-files tracker deleted modified)
-      tracker)))
+  (scan-dirs tracker dirs {:platform find/clj}))
 
 (defn scan-all
-  "Scans directories for all Clojure source files and updates the
+  "DEPRECATED: replaced by scan-dirs.
+
+  Scans directories for all Clojure source files and updates the
   dependency tracker to reload files. If no dirs given, defaults to
   all directories on the classpath."
+  {:added "0.2.0"
+   :deprecated "0.3.0"}
   [tracker & dirs]
-  (let [ds (or (seq dirs) (classpath-directories))
-        files (find-files ds)
-        deleted (seq (deleted-files tracker files))]
-    (update-files tracker deleted files)))
+  (scan-dirs tracker dirs {:platform find/clj :add-all? true}))
