example: added hetzner cloud workspace

ntimo · ntimo · commit 6a2c19235dbc · 2022-05-29T17:02:07.000Z
diff --git a/examples/hetzner-linux/README.md b/examples/hetzner-linux/README.md
@@ -0,0 +1,5 @@
+---
+name: Develop in Linux on Hetzner Cloud
+description: Get started with Linux development on Hetzner Cloud.
+tags: [cloud, hetzner]
+---
diff --git a/examples/hetzner-linux/main.tf b/examples/hetzner-linux/main.tf
@@ -0,0 +1,117 @@
+terraform {
+  required_providers {
+    coder = {
+      source  = "coder/coder"
+      version = "0.4.1"
+    }
+    hcloud = {
+      source  = "hetznercloud/hcloud"
+      version = "1.33.2"
+    }
+  }
+}
+
+provider "hcloud" {
+  token = var.hcloud_token
+}
+
+provider "coder" {
+}
+
+variable "hcloud_token" {
+  description = <<EOF
+Coder requires a Hetzner Cloud token to provision workspaces.
+EOF
+  sensitive   = true
+}
+
+variable "instance_location" {
+  description = "What region should your workspace live in?"
+  default     = "nbg1"
+  validation {
+    condition     = contains(["nbg1", "fsn1", "hel1"], var.instance_location)
+    error_message = "Invalid zone!"
+  }
+}
+
+variable "instance_type" {
+  description = "What instance type should your workspace use?"
+  default     = "cx11"
+  validation {
+    condition     = contains(["cx11", "cx21", "cx31", "cx41", "cx51"], var.instance_type)
+    error_message = "Invalid instance type!"
+  }
+}
+
+variable "instance_os" {
+  description = "Which operating system should your workspace use?"
+  default     = "ubuntu-20.04"
+  validation {
+    condition     = contains(["ubuntu-22.04","ubuntu-20.04", "ubuntu-18.04", "debian-11", "debian-10", "fedora-35"], var.instance_os)
+    error_message = "Invalid OS!"
+  }
+}
+
+variable "volume_size" {
+  description = "How much storage space do you need?"
+  default     = "50"
+  validation {
+    condition     = contains(["50","100","150"], var.volume_size)
+    error_message = "Invalid volume size!"
+  }
+}
+
+data "coder_workspace" "me" {
+}
+
+resource "coder_agent" "dev" {
+  arch = "amd64"
+  os   = "linux"
+}
+
+resource "hcloud_server" "root" {
+  count = data.coder_workspace.me.start_count
+  name        = "coder-${data.coder_workspace.me.owner}-${data.coder_workspace.me.name}-root"
+  server_type = var.instance_type
+  location    = var.instance_location
+  image       = var.instance_os
+  user_data   = <<EOF
+#!/bin/bash
+mkdir /home/coder/
+mount -o discard,defaults /dev/disk/by-id/scsi-0HC_Volume_${hcloud_volume.root.id} /home/coder/
+export CODER_AGENT_TOKEN=${coder_agent.dev.token}
+${coder_agent.dev.init_script}
+EOF
+}
+
+resource "hcloud_volume" "root" {
+  name         = "coder-${data.coder_workspace.me.owner}-${data.coder_workspace.me.name}-root"
+  size         = var.volume_size
+  format       = "ext4"
+  location     = var.instance_location
+}
+
+resource "hcloud_volume_attachment" "root" {
+  count     = data.coder_workspace.me.start_count
+  volume_id = hcloud_volume.root.id
+  server_id = hcloud_server.root[count.index].id
+  automount = false
+}
+
+resource "hcloud_firewall" "root" {
+  name = "coder-${data.coder_workspace.me.owner}-${data.coder_workspace.me.name}-root"
+  rule {
+    direction = "in"
+    protocol  = "icmp"
+    source_ips = [
+      "0.0.0.0/0",
+      "::/0"
+    ]
+  }
+}
+
+resource "hcloud_firewall_attachment" "root_fw_attach" {
+    count = data.coder_workspace.me.start_count
+    firewall_id = hcloud_firewall.root.id
+    server_ids  = [hcloud_server.root[count.index].id]
+}
