stm32/boards: stm32l43*.ld Add tunable FS sizes for 256 KiB parts.

chrismas9 · chrismas9 · commit a0943edffc16 · 2025-01-04T21:21:25.000+11:00
stm32/boards/stm32l43x_12kFS.ld
stm32/boards/stm32l43x_26kFS.ld
Replace stm32l432.ld with tunable versions for all stm32l43x parts.
The LENGTH(FLASH_FS) needs to be tuned for each board port to squeeze in
  drivers (eg USB, CANbus).
These changes allow editing one number (FS_SIZE) and all regions are
  calculated automatically.
stm32l43x_26kFS.ld provides a 26 KiB file system for minimal ports,
  eg NUCLEO_L432KC.
stm32l43x_12kFS.ld provides a 12 KiB file system for ports with USB.

stm32/boards/NUCLEO_L432KC/mpconfigboard.mk Use new stm32l43x_26kFS.ld.

Signed-off-by: Chris Mason &lt;c.mason@inchipdesign.com.au&gt;
diff --git a/ports/stm32/boards/NUCLEO_L432KC/mpconfigboard.mk b/ports/stm32/boards/NUCLEO_L432KC/mpconfigboard.mk
@@ -1,7 +1,7 @@
 MCU_SERIES = l4
 CMSIS_MCU = STM32L432xx
 AF_FILE = boards/stm32l432_af.csv
-LD_FILES = boards/stm32l432.ld boards/common_basic.ld
+LD_FILES = boards/stm32l43x_26kFS.ld boards/common_basic.ld
 OPENOCD_CONFIG = boards/openocd_stm32l4.cfg
 
 # MicroPython settings
diff --git a/ports/stm32/boards/stm32l43x_12kFS.ld b/ports/stm32/boards/stm32l43x_12kFS.ld
@@ -1,12 +1,19 @@
 /*
-    GNU linker script for STM32L432KC
+    GNU linker script for STM32L431xC STM32L432KC STM32L433xC STM32L442KC STM32L443xC.
+    FLASH 256K with 2K blocks, RAM 64K.
+    FLASH_FS length (FS_SIZE) is easily tunable to allow for adding features, eg USB, CANbus.
 */
 
-/* Specify the memory areas */
+/* Specify the memory areas.
+   FS_SIZE is not a region, it is only used to define the File System length.
+*/
 MEMORY
 {
-    FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 230K /* sectors 0-114 */
-    FLASH_FS (r)    : ORIGIN = 0x08039800, LENGTH = 26K /* sectors 115-127 */
+    ALL_FLASH (rx)  : ORIGIN = 0x08000000,  LENGTH = 256K
+    FS_SIZE (r)     : ORIGIN = 0,           LENGTH = 12K /* Adjust the File System size here */
+
+    FLASH (rx)      : ORIGIN = ORIGIN(ALL_FLASH), LENGTH = LENGTH(ALL_FLASH) - LENGTH(FS_SIZE)
+    FLASH_FS (r)    : ORIGIN = ORIGIN(FLASH) + LENGTH(FLASH), LENGTH = LENGTH(FS_SIZE)
     RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 64K /* SRAM1, 48K + SRAM2, 16K */
 }
 
diff --git a/ports/stm32/boards/stm32l43x_26kFS.ld b/ports/stm32/boards/stm32l43x_26kFS.ld
@@ -0,0 +1,41 @@
+/*
+    GNU linker script for STM32L431xC STM32L432KC STM32L433xC STM32L442KC STM32L443xC.
+    FLASH 256K with 2K blocks, RAM 64K.
+    FLASH_FS length (FS_SIZE) is easily tunable to allow for adding features, eg USB, CANbus.
+*/
+
+/* Specify the memory areas.
+   FS_SIZE is not a region, it is only used to define the File System length.
+*/
+MEMORY
+{
+    ALL_FLASH (rx)  : ORIGIN = 0x08000000,  LENGTH = 256K
+    FS_SIZE (r)     : ORIGIN = 0,           LENGTH = 26K /* Adjust the File System size here */
+
+    FLASH (rx)      : ORIGIN = ORIGIN(ALL_FLASH), LENGTH = LENGTH(ALL_FLASH) - LENGTH(FS_SIZE)
+    FLASH_FS (r)    : ORIGIN = ORIGIN(FLASH) + LENGTH(FLASH), LENGTH = LENGTH(FS_SIZE)
+    RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 64K /* SRAM1, 48K + SRAM2, 16K */
+}
+
+/* produce a link error if there is not this amount of RAM for these sections */
+_minimum_stack_size = 2K;
+_minimum_heap_size = 16K;
+
+/* Define the stack.  The stack is full descending so begins just above last byte of RAM,
+   or bottom of FS cache..  Note that EABI requires the stack to be 8-byte aligned for a call. */
+
+/* RAM extents for the garbage collector */
+_ram_start = ORIGIN(RAM);
+_ram_end = ORIGIN(RAM) + LENGTH(RAM);
+
+_micropy_hw_internal_flash_storage_ram_cache_end = _ram_end;
+_micropy_hw_internal_flash_storage_ram_cache_start = _micropy_hw_internal_flash_storage_ram_cache_end - 2K; /* fs cache = 2K */
+
+_estack = _micropy_hw_internal_flash_storage_ram_cache_start - _estack_reserve;
+_sstack = _estack - 10K; /* stack = 10K */
+
+_heap_start = _ebss; /* heap starts just after statically allocated memory */
+_heap_end = _sstack; /* bss + heap = 52K, tunable by adjusting stack size */
+
+_micropy_hw_internal_flash_storage_start = ORIGIN(FLASH_FS);
+_micropy_hw_internal_flash_storage_end   = ORIGIN(FLASH_FS) + LENGTH(FLASH_FS);
