Add RPC tutorial

hogimn · hogimn · commit 769883d5672d · 2024-06-22T19:22:20.000+09:00
diff --git a/erlang/README.md b/erlang/README.md
@@ -47,3 +47,8 @@ You need Erlang Client binaries:
 
     rebar3 shell --eval 'receive_logs_topic:start(["*.rabbit"]), init:stop().'
     rebar3 shell --eval 'emit_log_topic:start(["red.rabbit", "Hello"]), init:stop().'
+
+[Tutorial Six: RPC](https://www.rabbitmq.com/tutorials/tutorial-six-python.html):
+
+    rebar3 shell --eval 'rpc_server:start(), init:stop().'
+    rebar3 shell --eval 'rpc_client:start(["10"]), init:stop().'
diff --git a/erlang/rebar.config b/erlang/rebar.config
@@ -1,7 +1,8 @@
 {erl_opts, [debug_info]}.
 
 {deps, [
-    {amqp_client, "3.12.2"}
+    {amqp_client, "3.12.2"},
+    {uuid, {git, "https://github.com/okeuday/uuid.git", {tag, "v2.0.7"}}}
 ]}.
 
 {shell, [
diff --git a/erlang/rebar.lock b/erlang/rebar.lock
@@ -3,9 +3,17 @@
  {<<"credentials_obfuscation">>,
   {pkg,<<"credentials_obfuscation">>,<<"3.4.0">>},
   1},
+ {<<"quickrand">>,
+  {git,"https://github.com/okeuday/quickrand.git",
+       {ref,"65332de501998764f437c3ffe05d744f582d7622"}},
+  1},
  {<<"rabbit_common">>,{pkg,<<"rabbit_common">>,<<"3.12.2">>},1},
  {<<"recon">>,{pkg,<<"recon">>,<<"2.5.3">>},2},
- {<<"thoas">>,{pkg,<<"thoas">>,<<"1.0.0">>},2}]}.
+ {<<"thoas">>,{pkg,<<"thoas">>,<<"1.0.0">>},2},
+ {<<"uuid">>,
+  {git,"https://github.com/okeuday/uuid.git",
+       {ref,"7c2d1320c8e61e0fe25a66ecf4761e4b5b5803d6"}},
+  0}]}.
 [
 {pkg_hash,[
  {<<"amqp_client">>, <<"19770F1075FE697BEA8AA77E29DF38BD8A439F8D9F1D8A8FCCB56AE0C7AF73CD">>},
diff --git a/erlang/src/rpc_client.erl b/erlang/src/rpc_client.erl
@@ -0,0 +1,58 @@
+-module(rpc_client).
+-export([start/1]).
+
+-include_lib("amqp_client/include/amqp_client.hrl").
+
+start(Argv) ->
+    Num = case Argv of
+             [] -> 10;
+             [Arg] -> list_to_integer(Arg)
+          end,
+    io:format(" [x] Requesting fib(~p)~n", [Num]),
+    Response = call(Num),
+    io:format(" [.] Got ~p~n", [Response]),
+    ok.
+
+call(Num) ->
+    {ok, Connection} =
+        amqp_connection:start(#amqp_params_network{host = "localhost"}),
+    {ok, Channel} = amqp_connection:open_channel(Connection),
+    RequestQueue = <<"rpc_queue">>,
+    CorrelationId = uuid:get_v4(),
+
+    amqp_channel:call(Channel, #'queue.declare'{queue = RequestQueue}),
+
+    #'queue.declare_ok'{queue = ReplyQueue} =
+        amqp_channel:call(Channel, #'queue.declare'{exclusive = true}),
+
+    Method = #'basic.consume'{queue = ReplyQueue, no_ack = true},
+    amqp_channel:subscribe(Channel, Method, self()),
+
+    amqp_channel:cast(Channel,
+                      #'basic.publish'{
+                        exchange = <<>>,
+                        routing_key = RequestQueue},
+                      #amqp_msg{
+                        payload = integer_to_binary(Num),
+                        props = #'P_basic'{
+                            reply_to = ReplyQueue,
+                            correlation_id = CorrelationId}
+                        }),
+    
+    Response = wait_for_messages(CorrelationId),
+
+    amqp_channel:close(Channel),
+    amqp_connection:close(Connection),
+
+    Response.
+
+wait_for_messages(CorrelationId) ->
+    receive
+        {#'basic.deliver'{}, #amqp_msg{payload = Body, props = Props}} ->
+            #'P_basic'{correlation_id = CorrId} = Props,
+            if CorrelationId == CorrId ->
+                binary_to_integer(Body);
+            true ->
+                -1
+            end
+    end.
diff --git a/erlang/src/rpc_server.erl b/erlang/src/rpc_server.erl
@@ -0,0 +1,49 @@
+-module(rpc_server).
+-export([start/0]).
+
+-include_lib("amqp_client/include/amqp_client.hrl").
+
+start() ->
+    {ok, Connection} =
+        amqp_connection:start(#amqp_params_network{host = "localhost", heartbeat = 30}),
+    {ok, Channel} = amqp_connection:open_channel(Connection),
+
+    amqp_channel:call(Channel, #'queue.declare'{queue = <<"rpc_queue">>}),
+    io:format(" [*] Waiting for messages. To exit press CTRL+C~n"),
+
+    amqp_channel:call(Channel, #'basic.qos'{prefetch_count = 1}),
+
+    Method = #'basic.consume'{queue = <<"rpc_queue">>},
+    amqp_channel:subscribe(Channel, Method, self()),
+    loop(Channel).
+
+loop(Channel) ->
+    receive
+        {#'basic.deliver'{delivery_tag = DeliveryTag}, #amqp_msg{payload = Body, props = Props}} ->
+            #'P_basic'{reply_to = ReplyTo, correlation_id = CorrelationId} = Props,
+            Num = binary_to_integer(Body),
+            io:format(" [.] fib(~p)~n", [Num]),
+            Response = fib(Num),
+
+            amqp_channel:cast(Channel,
+                    #'basic.publish'{
+                        exchange = <<>>,
+                        routing_key = ReplyTo},
+                    #amqp_msg{
+                        payload = integer_to_binary(Response),
+                        props = #'P_basic'{
+                            correlation_id = CorrelationId}
+                        }),
+
+            amqp_channel:cast(Channel,
+                    #'basic.ack'{
+                        delivery_tag = DeliveryTag
+                    }),
+
+            loop(Channel)
+    end.
+
+fib(0) -> 0;
+fib(1) -> 1;
+fib(N) when N > 1 -> fib(N-1) + fib(N-2);
+fib(N) when N =< 0 -> -1.
