Scribd
Upload
72 views3 pages

SAP EDI Subsystem Documentation

This document provides documentation on SAP EDI subsystem record types, IDoc types, and the syntax used to describe them. It details the structure and elements of output for records, segments, groups, fields, and values. Key elements include records, segments, fields, groups, IDoc types, single values, and value ranges. The syntax is described using non-terminal and terminal symbols.

Uploaded by

Jorge FOS
Copyright
© © All Rights Reserved
We take content rights seriously. If you suspect this is your content, claim it here.
Available Formats
Download as DOCX, PDF, TXT or read online on Scribd
72 views3 pages

SAP EDI Subsystem Documentation

This document provides documentation on SAP EDI subsystem record types, IDoc types, and the syntax used to describe them. It details the structure and elements of output for records, segments, groups, fields, and values. Key elements include records, segments, fields, groups, IDoc types, single values, and value ranges. The syntax is described using non-terminal and terminal symbols.

Uploaded by

Jorge FOS
Copyright
© © All Rights Reserved
We take content rights seriously. If you suspect this is your content, claim it here.
Available Formats
Download as DOCX, PDF, TXT or read online on Scribd
You are on page 1/ 3

SAP EDI Subsystem Documentation

RE RSEIDOC3

____________________________________________________

Short Text
Documentation IDoc Record Types and IDoc Types (Parser)

Information about the syntax description


 Non-terminals can be recognized by the mixture of upper case and lower case characters. Terminals
comprise only upper case or only lower case letters.

 Empty is empty output.

 Explanatory comments are enclosed by /* and */.

 LF is the end-of-line character.

 An asterisk (*) after an expression means that the expression can occur as often as required.

 A plus sign (+) after an expression means that the expression must occur at least once.

 A selective (exclusive!) occurrence of several expressions is marked by an exclamation mark (!).

 Generally, each token is written in a new line with any subsequent value - <newline> or Linefeed/LF
are also used as delimiters. This is particularly useful for the fields TEXT and VALUE_TEXT. A free
text is output after the tokens TEXT and VALUE_TEXT, which mainly contains blanks. The line must
be ended by line feed so that new tokens are not identified as a result of these blanks. It was decided
not to enclose the free text in inverted commas, as the free text itself may contain these characters.

Syntax
Output ::= Records
Segments

/* The output comprises the two main parts records and segments. */

Records ::= empty !


BEGIN_RECORD_SECTION LF+
DC DD DS
END_RECORD_SECTION LF+

/* Records comprise the control, data, and status records. If the record types were not selected on the
selection screens, this section remains empty. */
DC ::= BEGIN_CONTROL_RECORD LF+
Fields
END_CONTROL_RECORD LF+

DD ::= BEGIN_DATA_RECORD LF+


Fields
END_DATA_RECORD LF+

DS ::= BEGIN_STATUS_RECORD LF+


Fields
END_STATUS_RECORD LF+

/* Each record is described by its fields. */

Fields ::= BEGIN_FIELDS LF+


Field+
END_FIELDS LF+

Field ::= NAME Alphanum LF+


TEXT (Alphanum ! empty) LF+
TYPE Alphanum LF+
LENGTH Num LF+
FIELD_POS Num LF+
CHARACTER_FIRST Num LF+
CHARACTER_LAST Num LF+
Values

Segments ::=empty !
BEGIN_SEGMENT_SECTION LF+
IDoc
END_SEGMENT_SECTION LF*

/* The IDoc type selected is output here. If no IDoc type is contained in the selection, this section remains
empty. */

IDoc ::= BEGIN_IDOC Alphanum LF+


(empty ! EXTENSION Alphanum LF+)
(Segment ! Group)+
END_IDOC LF+

/* An IDoc type comprises several segments and/or groups. The name of the current IDoc type is output
directly after the token BEGIN_IDOC. */

Segment ::= BEGIN_SEGMENT Alphanum LF+


LEVEL Num LF+
STATUS Status LF+
LOOPMIN Num LF+
LOOPMAX Num LF+
Fields
END_SEGMENT LF+

/* The attributes and the assigned fields are output for each segment. The name of the current segment is
output directly after the token BEGIN_SEGMENT. */

Group ::= BEGIN_GROUP Num LF+


LEVEL Num LF+
STATUS Status LF+
LOOPMIN Num LF+
LOOPMAX Num LF+
Segment
(Segment ! Group)*
END_GROUP LF+

/* A group has group attributes which are stored in the first segment. The first segment itself possesses default
attributes. This first segment is also used to identify the beginning of the group within an IDoc type for
repetitions. Other segments and groups can follow subsequently. The number of the current group is output
directly after the token BEGIN_GROUP. */

Values ::= (Single ! Range)* !


VALUE_TABLE Alphanum LF+

/* Values are either defined in the domain (single values/Single or ranges/Range), or there is an assigned value
table. If no values can be found, this output does not occur. */

Single ::= VALUE 'Alphanum' LF+


VALUE_TEXT (Alphanum ! empty) LF+

Range ::= VALUE_RANGE 'Alphanum' - 'Alphanum' LF+


VALUE_TEXT (Alphanum ! empty) LF+

/* A single value is output for Single, a range for Range. Here the alphanumeric output is enclosed in inverted
commas. It is followed by the comment stored in the domain. */

Alphanum ::= (A-Z, a-z, ' ', 0-9)*


Num ::= (0-9)+
Status ::= MANDATORY ! OPTIONAL

/* The status determines whether a segment or group must or can occur.*/

You might also like

pFad - Phonifier reborn

Pfad - The Proxy pFad of © 2024 Garber Painting. All rights reserved.

Note: This service is not intended for secure transactions such as banking, social media, email, or purchasing. Use at your own risk. We assume no liability whatsoever for broken pages.


Alternative Proxies:

Alternative Proxy

pFad Proxy

pFad v3 Proxy

pFad v4 Proxy